National Lampoon's Blind Date/National Lampoon's Blind Date.iso/bd/part1.mmm/00413_Script_413

Text File | 1995-03-01 | 7KB | 240 lines

----------------------------------------------------------------
on startMovie
  global theFunds, moodRing, wallaOn, vol

  set the text of cast 908 to "$" & theFunds
  addMood(0)
  updateStage
  set wallaOn = FALSE
  set vol = 255
  set the volume of sound 1 to 255
end startMovie
----------------------------------------------------------------
on setUpFirstFrame
  setUpNoFade()
end setUpFirstFrame
----------------------------------------------------------------
on setUpNoFade
  global wallaOn, hintLock

  releaseMouseUp()
  set wallaOn = FALSE
  puppetSound 0
  set the volume of sound 1 to 255
  set hintLock = FALSE
end setUpNoFade
----------------------------------------------------------------
on waitForMovie chan
  global wallaOn

  waitMovieNoSound(chan)
  set wallaOn = TRUE
end waitForMovie
----------------------------------------------------------------
on waitMovieNoSound chan
  repeat while the movieRate of sprite chan > 0
    updateStage
    if mouseDown() then
      set the movieTime of sprite chan to ¼
      (the duration of cast (the castNum of sprite chan)) - 1
      updateStage
      exit repeat
    end if
  end repeat
end waitMovieNoSound
----------------------------------------------------------------
on loopLastFrame
  releaseMouseUp()
  if the movieRate of sprite 9 = 0 then
    loopLastNoMovie()
  else
    go to the frame
  end if
end loopLastFrame
----------------------------------------------------------------
on loopLastNoMovie
  global wallaOn, vol

  releaseMouseUp()
  if wallaOn then
    if not soundBusy(1) and not mouseDown() then
      fadeInWalla()
    else if vol < 255 then
      set vol = vol + 5
      set the volume of sound 1 to vol
    end if
  end if
  go to the frame
end loopLastNoMovie
----------------------------------------------------------------
on trapMouseUp
  repeat while mouseDown()
    if the timer > 50 then exit repeat
  end repeat
  when mouseUp then dontPassEvent
end
----------------------------------------------------------------
on releaseMouseUp
  when mouseUp then nothing
end
----------------------------------------------------------------
on doNextNoClick nextFrame
  go to frame nextFrame
end doNextNoClick
----------------------------------------------------------------
on doNextScene nextFrame
  PlayDown()
  doNextNoClick(nextFrame)
end doNextFrame
----------------------------------------------------------------
on doMovieFrame theMovie, theFrame
  puppetSound 0
  go to frame theFrame of movie theMovie
end doNextFrame
----------------------------------------------------------------
on fadeInMusic
  global currSong, wallaOn, vol

  set the volume of sound 1 to 25
  if currSong = 1 then
    puppetSound "unbelwal.aif"
  else if currSong = 2 then
    puppetSound "song4wal.aif"
  else if currSong = 3 then
    puppetSound "song3wal.aif"
  else
    puppetSound "song2wal.aif"
    set currSong = 0
  end if
  set currSong = currSong + 1
  set wallaOn = TRUE
  set vol = 0
end fadeInMusic
----------------------------------------------------------------
on fadeInWalla
  fadeInMusic()
end fadeInWalla
----------------------------------------------------------------
on fadeBackIn
  global wallaOn, currSong

  if wallaOn = TRUE then
    set currSong = currSong - 1
  end if
end fadeBackIn
----------------------------------------------------------------
on doStopper
  global currStopper

  puppetsound 0
  puppetSprite 7, FALSE

  set currStopper = currStopper + 1
  if currStopper > 11 or currStopper < 1 then
    set currStopper = 1
  end if

  go to frame "st" & currStopper of movie "MovStop.MMM"
end doStopper
----------------------------------------------------------------
on doStopper2 frm
  puppetSound 0
  go to frame frm of movie "MovStop.MMM"
end doStopper2
----------------------------------------------------------------
on doDrinkLoop retScene
  global returnScene
  global Drinks

  set returnScene = retScene
  set Drinks = Drinks + 1
  if Drinks = 1 then
    doNextScene("s84")
  else if Drinks = 2 then
    doNextScene("s88")
  else if Drinks = 3 then
    doNextScene("s92")
  else
    doNextScene("s93")
  end if

end doDrinkLoop
----------------------------------------------------------------
on deductFunds howMuch, chan
  global hintLock

  set hintLock = TRUE
  addFunds(-howMuch)
  puppetSound "cash.AIFF"
  puppetSprite chan, 1
  set the visibility of sprite chan to 1
  repeat while the locV of sprite chan > ¼
    -(the height of sprite chan)
    set the locH of sprite chan = the locH of sprite chan - 1
    set the locV of sprite chan = the locV of sprite chan - 1
    updateStage
  end repeat
  puppetSprite chan, 0
  repeat while soundbusy(1)
    nothing
  end repeat
end deductFunds
----------------------------------------------------------------
on addFunds howMuch
  global theFunds

  set theFunds = theFunds + howMuch
  set the text of cast 908 to "$" & theFunds
end
----------------------------------------------------------------
on addMood mood
  global moodRing

  set ringChan = 14
  puppetSprite ringChan, TRUE
  set moodRing = moodRing + mood
  if moodRing < -4 then
    -- alert "mood ring too low"
    set moodRing = -4
    set the castNum of sprite ringChan to 922 + moodRing
    updateStage
    doStopper2("Mood")
    return FALSE
  else if moodRing > 4 then
    set moodRing = 4
  end if
  set the castNum of sprite ringChan to 922 + moodRing
  updateStage
  --puppetSprite ringChan, FALSE
  return TRUE
end addMood
----------------------------------------------------------------
on addMoodAndGo mood, scene
  if addMood(mood) then
    -- then the mood was not too low
    doNextScene(scene)
  end if
end addMoodAndGo
----------------------------------------------------------------
on doEasterEgg egg, retScene
  global returnScene

  set returnScene = retScene
  go to frame egg
end doEasterEgg
----------------------------------------------------------------
on getLabel

  set currFrame = marker(0)
  set n = the number of lines in the labelList
  set i = 1
  repeat while i <= n
    if label(line i of the labelList) = currFrame then
      return line i of the labelList
    else
      set i = i + 1
    end if
  end repeat
  return line 1 of the labelList
end getLabel